Add a rough build all parallel batch script

buildAllParallel.bat

@@ -0,0 +1,35 @@
+@echo off & setlocal enabledelayedexpansion
+
+
+echo ==================== Getting versions to build... ====================
+mkdir _buildAllJars 2>nul
+del _buildAllJars\* /Q 2>nul
+
+set "ROOT=%~dp0"
+set "WORK_DIR=%ROOT%_buildWorkers"
+mkdir "%WORK_DIR%" 2>nul
+
+
+REM get the number of versions to compile
+set count=0
+for %%f in (versionProperties\*) do set /a count+=1
+echo ==================== Found %count% versions to build in parallel ====================
+
+REM Launch a parallel job for each version
+for %%f in (%ROOT%versionProperties\*) do (
+    set version=%%~nf
+	
+	echo starting [!version!]...
+    start "Build !version!" cmd /c ""%ROOT%build_worker.bat" "!version!" "%ROOT%" "%WORK_DIR%" ""..\..\_buildAllJars"""
+	
+	REM Minor timeout between launches so we can stop the build early if we only want 
+	REM to test part of the script and to reduce startup load
+	timeout /t 3 /nobreak
+	
+REM 2>nul to supress a harmless warning that the for loop
+REM "cannot find the drive specified"
+) 2>nul
+
+
+echo ==================== All builds started... Completed Jars will be in _buildAllJars ====================
+endlocal

build_worker.bat

@@ -0,0 +1,41 @@
+@echo off & setlocal enabledelayedexpansion
+
+set "VERSION=%~1"
+set "ROOT=%~2"
+set "WORK_DIR=%~3"
+set "WORKER=%WORK_DIR%\%VERSION%"
+set "JAR_OUTPUT_DIR=%~4"
+
+REM remove the ending "\" from the root folder, otherwise the final quote
+REM in the robocopy command will be escaped and it won't run
+if "%ROOT:~-1%"=="\" set "ROOT=%ROOT:~0,-1%"
+set "WORKER=%~3\%~1"
+
+set "BUILT_JAR_DIR=%WORKER%\build\forgix"
+
+
+
+echo ==================== [%VERSION%] Copying workspace ====================
+mkdir "%WORKER%"
+robocopy "%ROOT%" "%WORKER%" /E /XD "%WORKER%" "_buildWorkers" "buildAllJars" ".gradle" "build" ".git" ".idea" ".gitlab" "run" "testScripts" /NFL /NDL
+
+echo ==================== [%VERSION%] Cleaning ====================
+cd /d "%WORKER%"
+call .\gradlew.bat clean 
+REM optional arg that can be added if we want to log the result to a file
+REM >"%WORK_DIR%\build_%VERSION%.log" 2>&1
+
+echo ==================== [%VERSION%] Assembling ====================
+call .\gradlew.bat assemble -PmcVer="%VERSION%" 
+REM optional arg that can be added if we want to log the result to a file
+REM >>"%WORK_DIR%\build_%VERSION%.log" 2>&1
+
+echo ==================== [%VERSION%] Exporting ====================
+mkdir "%JAR_OUTPUT_DIR%"
+robocopy "%BUILT_JAR_DIR%" "%JAR_OUTPUT_DIR%" /NFL /NDL
+
+echo ==================== [%VERSION%] Done ====================
+endlocal
+
+REM can be uncommented for debugging
+REM pause